/* DickensDrinking 
 * by Erica Liszewski
 * on November 18, 2007
 * for DMST3211
 *
 * DickensDrinking is a visualization of how much alchohol one would
 * consume by playing the Dickens Drinking Game in real life.  The Game
 * is played by reading a Dickens novel ( 5 selections are provided ) 
 *  and taking a drink when one comes accross
 * the words "ale", "wine", "gin", or "beer".  One should, in theory,
 * have a container of each of these liqours on hand, and drink to the 
 * appropriate one, but I have not yet implemented this feature.
 *
 * Users can select the story they'd like to see from the buttons on 
 * the right.
 */

//for separating out words
String separators = WHITESPACE + "/<>*_,:.;?!()\"-";

//setup for books and titles
String[] titles = {"Little Dorrit", 
                   "David Copperfield", 
                   "Oliver Twist", 
                   "The Tale of Two Cities",
                   "Great Expectations"};
String[] files = {"LittleDorrit", 
                  "DavidCopperfield", 
                  "OliverTwist", 
                  "TaleOfTwoCities",
                  "GreatExpectations" };

WineManager wine;//manages the wine
int line_count;//keeps track of what line we're on
String[] lines = {"Please Choose a Story"};//contains the novels
String title = "";//the title of the current novel
PFont font;//for displaying text
String chapter = "Please Choose a Story";//the chapter text at the top
float framerate;//framerate is variable
TitleButton[] buttons;//contains the buttons

void setup(){
  size(600, 450);
  wine = new WineManager(width-100, height-40, 0, 70);
  framerate = 5;
  frameRate(framerate);
  background(255); 
  line_count = 0;
  font = loadFont("AmericanTypewriter-Condensed-20.vlw");
  textFont(font);
  setupButtons();
}

void draw(){
  background(255); //clear
  boolean chapter_end = false; //we are starting a chapter
  /* used for a slightly different visualization */
//  if(line_count < lines.length){
  //loop through lines until the end of a chapter
  while(line_count < lines.length && !chapter_end){
    //split the words out of each line
    String[] words = splitTokens(lines[line_count], separators);
    //setup for drawing text
    fill(0);
    /* used for a slightly differnt visualization */
//    text(lines[line_count], 5, 57);

    //for each word
    for(int i=0; i< words.length; i++){
      //lowercase and remove any remaining whitespace
      String word = (words[i].trim()).toLowerCase();
      //if we find some sort of alcohol, "sip" the wine
      if(word.equals("wine")){
        wine.sip(); 
      }
      else if(word.equals("gin")){
        wine.sip();
      }
      else if(word.equals("ale")){
        wine.sip();
      }
      else if(word.equals("beer")){
        wine.sip();
        //if we find chapter, we're starting the next chapter
      }else if(words[i].equals("CHAPTER")){
        if(i+1 < words.length) chapter = words[i] + " " + words[i+1]; 
        chapter_end = true;
      }
    }
    line_count++; //increment line
  }
  //render the text at the top
  fill(0);
  textFont(font);
  textSize(20);
  text("Dickens Drinking Game, "+title, 5, 21);
  textFont(font);
  textSize(18);
  text(chapter, 5, 41);
  //render the wine
  wine.render(); 
  //render the buttons
  for(int i=0; i<buttons.length; i++){
   buttons[i].render(); 
  }
}

//decide if we pressed a button, and change novels
void mousePressed(){
  if(mouseX>width-100){
   for(int i=0; i<buttons.length; i++){
     if(buttons[i].containsY(mouseY)){
        title = buttons[i].title;
        line_count = 0;
        lines = loadStrings(buttons[i].file);
        wine.clear();   
     }
    }
  }
}

//sets up the buttons on the right
void setupButtons(){
  buttons = new TitleButton[titles.length];//init the array
  //init upper left corner
  int start_x = width-100;
  int start_y = 70;
  for(int i = 0; i< titles.length; i++){
    //create
   TitleButton t1 = new TitleButton(titles[i], files[i], start_x, start_y, 100, 40);
   buttons[i] = t1;
   //increment y of upper right corner
   start_y+=60; 
  }
}

/* public class TitleButton
 * creates and displays a button for the titles 
 * of the stories
 */
public class TitleButton{
 String title;//the title, as it will be displayed
 String file;//the name of the file containing the book
 int x, y;//upper right coner
 int my_width, my_height;//duh

  public TitleButton(String t, String f, int x, int y, int w, int h){
   this.title = t;
   this.file = f+".txt";
   this.x = x;
   this.y = y;
   this.my_width = w;
   this.my_height = h;
  } 
  
  public void render(){
    //draw the rectange
   fill(0);
   rect(x, y, my_width, my_height);
   //draw the text
   textFont(font);
   textSize(16);
   fill(255);
   text(title, x+5, y+5, my_width-10, my_height-10);
  }
  
  //see if it contains the input Y value
  public boolean containsY(int y){
    if(y>this.y && y< this.y+my_height) return true;
    else return false;
  }
  
}